G50V - Anyone find a use for the OLED display?

Finalized Volume module.

The 6 side panels are pretty much done.

There's still a huge space in the middle for me/you to add other modules later on.

Enjoy.

 

Hey! Hi to all!
I'm from spain and i bought an Asus G50v.
i'm working at the mega script to adapted with the G50v's oled....
only left for me a driver which works properly.... because actually driver only works with touchpad led!
anybody can tell me if there is a driver which works properly???

sorry, of my english!

Pd: I have to give thanks for the program and the mega script, it's great because it too worked!!! congratulations!!!

 

Ram display still not working right for me...also what is the Volumes section supposed to do? Doesn't seem to work for me.

 

Did you extract it properly? The battery and volume plugins have to be in the plugin folder in the main LCDHype folder.

The RAM uses the core program's plugins, are you sure you're using the most up-to-date LCDHype (v 0.6)?

 

Volume plugin doesn't work on G50Vs, I had tried this plugin why another guy on a french forum, we could see the name of the sound card (tested the integrated sound card and an external one), the number of mixers and the channels detected, but impossible to get the volume or mute information, I don't know why... It seems it works on the G50Vt

 

people, could you tell me if there is a script which works, properly for controll the asusG50v's LEDS????

How can i contact with predator_MF????

 

Have some patience, predator is working on with LED script. He reads this thread/forum, so if you have feedback you can post it here.

 

Some kind of integration with Google Reader would be swell, but I highly doubt that'll ever happen.

 

Hey guys,

Just figured I'd throw in what I've done for my LCD screen. Some of it is customized specifically for my configuration, but I just thought I'd show off my few hours of work.

The network screen doesn't fill the whole thing because I was going to put something for ethernet there, but haven't gotten around to it.

And yeah, I know there are some logo copyrights but I'm not making money off of this, and it looks better than just a plain "CPU" or "GPU" label

 

Looks good!
Throw up your script, I'd like to take a look at it.

 

Put current Download/Upload speed and IP

 

I like!! I'd love to see how you coded them.

 

Hi Predator-- I should thank you for your Megascript, and I will openly admit that I did copy/paste/edit the occasional chunk of code from it. Excellent work you have there! I wasn't originally planning on sharing the source with anyone, so forgive me for not crediting you within the code below.

I used the Everest plugin, battery plugin (works even though I get an error somewhere in the CPU/RAM screen code), and the only images were the little WiFi logo and the HDD/CPU/GPU logos that I also copied and edited for my personal use. Awesomeness credit to Predator_MF for the Megascript, which I referred to for coding examples repeatedly.

As a disclaimer I am not making any money off of this, nor am I trying to get into any copyright troubles, and I will gladly edit something at the threat of some company/person suing me (not worth it). Anyone is free to copy the code and do whatever with it, but if you do end up making money I totally expect at least 10% for myself (and some to Predator, too).

Battery/CPU/RAM status
View attachment 29895
My first completed screen, should work for anyone with the battery plugin. Just take out the line that has the "%Common.ChangeScreen" in it.

Code:

#Header
   %Common.SetPriority(1875)
   %Graph.SetTextArea(0,0,256,32)
   %Param.RenderMode(Simple)
   %DefVar(state,local=0)
   %DefVar(battPct,Local = 0)
   %DefVar(AC,Local=0)
   %DefVar(CPUusage, Local=0)
   %DefVar(RAM,Local=0)
   %DefVar(hourPM,Local=0)
   %DefVar(hourAM,Local=0)
   %DefFunc(BattFlag=%UsePlugin('battery\batteryplugin.dll',nBatteryFlag))
   %DefFunc(ACFlag=%UsePlugin('battery\batteryplugin.dll',nACFlag))
   %DefFunc(LifeTime=%UsePlugin('battery\batteryplugin.dll',LifeTime))
   %DefFunc(IdleTime=%UsePlugin('battery\batteryplugin.dll',nSystemIdleTime))
#EndHeader

#GfxMode
%Common.ChangeScreen(7500,3)

/Get Variables/

%Assign(battPct,%UsePlugin('battery\batteryplugin.dll',LifePercent))
%Assign(CPUusage,%System.CPU(Usage))
%Assign(RAM,%System.Memory(MemoryLoad))
%Assign(hourPM,%Dec(%System.GetDateTime(hh),12))
%Assign(hourAM,%Dec(%System.GetDateTime(hh),0))
/Display Variables/

/Time/
%Format.AlignRight()
%KeyCheck()
%If(%hourPM() = 0)Then{%Assign(hourPM,%Dec(%System.GetDateTime(hh),0))}
%If(%hourAM() = 0)Then{%Assign(hourAM,%Dec(%System.GetDateTime(hh),-12))}
%Common.CreateNewLine(,0,-2)
%Graph.Font('Arial',11,1,Bold)
%If(%System.GetDateTime(h) < 12)
Then{%hourAM()%System.GetDateTime(':nn ')AM%Common.CreateNewLine(,0,12,)%Graph.Font('Tahoma',7,1)%System.GetDateTime('dddd')%Common.CreateNewLine(,0,21)%System.GetDateTime('mmmm d')}
Else{%hourPM()%System.GetDateTime(':nn ')PM%Common.CreateNewLine(,0,12,)%Graph.Font('Tahoma',7,1)%System.GetDateTime('dddd')%Common.CreateNewLine(,0,21)%System.GetDateTime('mmmm d')}

/CPU/
%Graph.Font('Trebuchet MS',10,1,Bold)
%Format.AlignRight()
%Common.CreateNewLine(,70,-3)
'CPU: '%CPUusage()'%'
%Format.Bar(Horizontal,50,12,0,100,%CPUusage(),1,1,140,0)

/RAM/
%Format.AlignLeft()
%Common.CreateNewLine(,70,15)
'RAM: '%RAM()'%'
%Format.Bar(Horizontal,50,12,0,100,%RAM(),1,1,140,18)

/Battery/
%Graph.Font('Trebuchet MS',15,1,Bold)
%Format.AlignLeft()
%Common.CreateNewLine(,,-4)
%battPct() %Graph.Font('Tahoma',10,1) '%'
%Common.CreateNewLine(,0,19)
%Graph.Font('Tahoma',7,1)
%If(%ACFlag() = 1)
Then { 'Plugged In'
%If(%battPct() < 96) Then {%Common.CreateNewLine(,35,0) %Graph.Font('Webdings',11,1)~}}
Else{
%If(%LifeTime() = -1) Then {'Calculating'}
Else {%LifeTime()
}
}
%Graph.Rect(53,0,57,4,3,1)
%Format.Bar(Vertical,11,29,0,100,%battPct(),2,1,50,3)


#EndGfxMode

Wireless status (the unfinished one).
View attachment 29893
This is customized for my computer, and if you copy/paste it you might need to change all the %System.Network(x,[parameter]) to something other than x=10 (whatever # your wireless connection happens to be). Also, the bars are made to only scale to 300Mbps, so if you have an adapter that runs at 450Mbps, you might find some extra bars running into things. The cool things about this one is that wireless G makes up to 6 bars, and then if wireless N speeds are detected, it adds on up to 3 unfilled bars.
This also uses the image wifi.bmp. View attachment wifi.bmp

Code:

#Header
   %Common.SetPriority(2500)
   %Graph.SetTextArea(0,0,256,32)
   %Param.RenderMode(Simple)
   %DefVar(hourPM,Local=0)
   %DefVar(hourAM,Local=0)
   %DefVar(WiFiSpeed,Local=0)
   %DefVar(C,Local=0)
   %DefVar(Bars,Local=0)

  / %Graph.SetInvertArea(0,0,68,32)/
#EndHeader


#GfxMode
%Common.ChangeScreen(5000,5)
%CleanUp.ClearVRAM()
%Graph.LoadBitmap('wifi.bmp',68,0,0,0,29,13,0,NONE)
%Assign(WiFiSpeed,%System.Network(10,Speed))
/%Assign(WiFiSpeed,300)/


/%Graph.Font('Tahoma',8,1)
%Common.CreateNewLine(,00,0)
%System.Network(11,Name)/


/Wireless Bar/
%Graph.Font('Tahoma',11,1,Bold)
%Common.CreateNewLine(,70,-4)
%Format.AlignLeft()
%Graph.Font('Tahoma',7,1,)
%Common.CreateNewLine(,115,10)
%Div(%Round(%Div(%System.Network(10,PacketsIn),10485.76)),100)' MB in'
%Common.CreateNewLine(,115,20)
%Div(%Round(%Div(%System.Network(10,PacketsOut),10485.76)),100)' MB out'


%Common.CreateNewLine(,115,-2)
%Graph.Font('Tahoma',9,1,Bold)

%If(%WiFiSpeed() > 54) Then{
'n'
%Assign(Bars,9)
%Assign(Bars,%Round(%Div(%Dec(%WiFiSpeed(),54),100)))
%Loop.For(C,1,6,1){
%Graph.Rect(
%Inc(%Mul(%C(),4),68),
30,
%Inc(%Mul(%C(),4),70),
%Dec(30,%Mul(2,%C())),
1,
1)
}

%Loop.For(C,7,%Inc(%Bars(),7),1){
%Graph.Rect(
%Inc(%Mul(%C(),4),68),
30,
%Inc(%Mul(%C(),4),70),
%Dec(30,%Mul(2.2,%C())),
1,
0)
}
}
Else{
'G'
%Assign(Bars,%Round(%Div(%WiFiSpeed(),9)))
%Loop.For(C,1,%Bars(),1){
%Graph.Rect(
%Inc(%Mul(%C(),4),68),
30,
%Inc(%Mul(%C(),4),70),
%Dec(30,%Mul(3,%C())),
1,
1)
}
}
%Graph.Font('Tahoma',7,1)
%Common.CreateNewLine(,125,0)' @ '
%WiFiSpeed()' Mbps'

/%Common.CreateNewLine(,110,20)hi/


/Time/
%Assign(hourPM,%Dec(%System.GetDateTime(hh),12))
%Assign(hourAM,%Dec(%System.GetDateTime(hh),0))
%Format.AlignLeft()
%If(%hourPM() = 0)Then{%Assign(hourPM,%Dec(%System.GetDateTime(hh),0))}
%If(%hourAM() = 0)Then{%Assign(hourAM,%Dec(%System.GetDateTime(hh),-12))}
%Common.CreateNewLine(,0,-2)
%Graph.Font('Arial',10,1,Bold)
%If(%System.GetDateTime(h) < 12)
Then{%hourAM()%System.GetDateTime(':nn ')am%Common.CreateNewLine(,0,12,)%Graph.Font('Tahoma',7,1)%System.GetDateTime('dddd')%Common.CreateNewLine(,0,21)%System.GetDateTime('mmmm d')}
Else{%hourPM()%System.GetDateTime(':nn ')pm%Common.CreateNewLine(,0,12,)%Graph.Font('Tahoma',7,1)%System.GetDateTime('dddd')%Common.CreateNewLine(,0,21)%System.GetDateTime('mmmm d')}


#EndGfxMode

The temperatures/hard drive status.
View attachment 29894
This is also customized for my computer, as I put in a second hard drive (letter F). If you copy/paste this, you might need to play with the hard drive bar placement or set the drive to a different letter/partition. Temperatures will also be messed up if you only have a single drive.
This also uses the image hdd.bmp. View attachment hdd.bmp

Code:

#Header
   %Common.SetPriority(3500)
   %Graph.SetTextArea(0,0,256,32)
   %Param.RenderMode(Simple)
   %DefVar(hourPM,Local=0)
   %DefVar(hourAM,Local=0)
   %DefVar(Str,Local='hi')
   %Graph.SetInvertArea(112,0,199,32)
   /%Graph.Pen(10,16,1)
   %Graph.LineTo(95,16,1)/
   %Graph.LoadBitmap('hdd.bmp',29,0,0,0,50,32,0,NONE)
#EndHeader



#GfxMode
%Common.ChangeScreen(7000,'Initial')
%Graph.Font('Arial',9,1,Bold)
%Common.CreateNewLine(,0,-1)
%If(%UsePlugin('everest\everest.dll',THDD1,value) = 'Everest is not running') Then{
''
}
Else{
%UsePlugin('everest\everest.dll',THDD1,value)'°C'
%Common.CreateNewLine(,82,-1)
%UsePlugin('everest\everest.dll',THDD2,value)'°C'
%Common.CreateNewLine(,0,16)
%UsePlugin('everest\everest.dll',TCC-1-1,value)'°C'
%Common.CreateNewLine(,82,16)
%UsePlugin('everest\everest.dll',TGPU1DIO,value)'°C'
}



%Graph.Font('Tahoma',8,1,Bold)
%Common.CreateNewLine(,114,-2)
'C'
%Common.CreateNewLine(,114,8)
'D'
%Common.CreateNewLine(,114,19)
'F'
%Graph.Font('Tahoma',8,1,)
%Common.CreateNewLine(,176,-2)
%System.Drive(C,Load)'%'
%Common.CreateNewLine(,176,8)
%System.Drive(D,Load)'%'
%Common.CreateNewLine(,176,19)
%System.Drive(F,Load)'%'

%Format.Bar(Horizontal,50,10,0,100,%System.Drive(C,Load),1,1,123,0)
%Format.Bar(Horizontal,50,10,0,100,%System.Drive(D,Load),1,1,123,11)
%Format.Bar(Horizontal,50,10,0,100,%System.Drive(F,Load),1,1,123,22)
%Common.CreateNewLine(,0,0)
%Format.AlignRight()

%Graph.Font('Tahoma',8,1)
%Common.CreateNewLine(,0,15)
%Div(%Round(%Div(%Inc(%Inc(%System.Drive(C,Free),%System.Drive(D,Free)),%System.Drive(F,Free)),104857.6)),10)' GB'
%Common.CreateNewLine(,,,)



/Time/
%Assign(hourPM,%Dec(%System.GetDateTime(hh),12))
%Assign(hourAM,%Dec(%System.GetDateTime(hh),0))
%Format.AlignRight()
%If(%hourPM() = 0)Then{%Assign(hourPM,%Dec(%System.GetDateTime(hh),0))}
%If(%hourAM() = 0)Then{%Assign(hourAM,%Dec(%System.GetDateTime(hh),-12))}
/%Graph.Font('Tahoma',8,1)
%Common.CreateNewLine(,0,-2)
%System.GetDateTime(ddd)''/
%Graph.Font('Tahoma',9,1,Bold)
%Common.CreateNewLine(,0,-3)
/%hourPM()%System.GetDateTime(':nn')/
%If(%System.GetDateTime(h) < 12)
Then{%hourAM()%System.GetDateTime(':nn')'am'}
Else{%hourPM()%System.GetDateTime(':nn')'pm'}

#EndGfxMode

If anyone has any questions, suggestions, or optimizations, don't hesitate to field them! I appreciate everyone's input and interest in all this.

 

Great work I don't mind you taking snippets from my code, that's why I share it free for all, you can use, modify, alter in any way.

Now, since the Megascript is made so easy to integrate scripts into, all you need to do is add KeyInit() in the header of your scripts and KeyCheck() in their bodies. Then you put them after the last custom script (or replace any of them with your ones), add the line %List.Add(MenuNames,'My script name') and you have it on the megascript with full menu functionality

 

Could somebody zip this up for us?

 

Excuse me,
What do this line??? because i'm trying to write the message and the user who sende me the message, in the script skype popup event and only give me Error[4]... and afther this mi name in the skype...

%Assign(SkypeClientName,%UsePlugin('Skype\Skype.dll',MissedChatInfo, Name, 1/chatnumber/))

What am i doing wrong???

adding, i would like, to do in the script(msn & skype, in both of them), something to read all lines of the conversation, because sometimes people write me many lines....
anybody could help me?

Here is the code:

PHP:

#Header
%KeyInit()
%CleanUp.ClearVRAM()
%Common.SetPriority(20)
%LCD.Gfx_SetTextArea(0,0,255,31)
%Param.RenderMode(Full)
%Graph.SetInvertArea(30,0,255,10)
%Graph.Font('Arial',7,1)

%DefVar(i=0)
%DefVar(TStart = %System.Uptime())
%DefVar(stime = 0)

   %DefFunc(Skype_running=
      %If((%System.GetProcessID('skype.exe') ! 0))
      Then{1}
      Else{0}
   )
   
%DefVar(SkypeName='')
%DefVar(SkypeClientName='')
%DefVar(SkypeStatus='')
%DefVar(MissedChats='')
%DefVar(MissedCalls='')
   
%Graph.LoadBitmap('gfx\skype24.bmp',0,0,0,0,24,24,0,NONE)
#EndHeader

#GfxMode
%KeyCheck()
/%UsePlugin('Skype\Skype.dll',ClientInfo, Name, 0/contact/)/
%If(%Dec(%System.Uptime(), %stime()) > 2000)
Then{
     %Assign(stime, %System.Uptime())
     %Assign(SkypeName, %UsePlugin('Skype\Skype.dll',MyInfo, Name))
     %Assign(SkypeClientName,%UsePlugin('Skype\Skype.dll',MissedChatInfo, Name, 1/chatnumber/))
     %Assign(SkypeStatus, %UsePlugin('Skype\Skype.dll',MyInfo, Status))
     %Assign(MissedChats, %UsePlugin('Skype\Skype.dll',MissedChatCount))
     %Assign(MissedCalls, %UsePlugin('Skype\Skype.dll',MissedCallCount))
    }

%Common.CreateNewLine(,1,21)
'Skype'

%Common.CreateNewLine(30,32,0)
%Param.EnableScrolling(Horizontal,Ticker,0.6,255,1,0)
%SkypeName()
%Param.OverlayMode()

%Common.CreateNewLine(30,30,10)
%If(%SkypeLED() = 0)
Then{
      'Status: ' 
      %SkypeStatus()
    }
Else{
      'New '
      %If(%MissedChats() ! 0)
      Then{'Chats: ' %MissedChats()}' '
      %If(%MissedCalls() ! 0)
      Then{'Calls: ' %MissedCalls()}
    }
//
//
%If(%SkypeLED() ! 0)
Then{
      %Common.CreateNewLine(30,32,18)
      %Graph.Font('Arial',8,0)
      %Graph.Rect(30,20,255,31,1,1)
      %Param.EnableScrolling(Horizontal,Ticker,1,255,1,0)
      %SkypeClientName()
      %SkypeLine()
    }
    
%If((%Dec(%System.Uptime(),%TStart()) > 20000) OR (%SkypeLED() = 0))
 Then{
 %PopupExit(0)
}
#EndGfxMode

 

Yes, me!
mmm, i love your idea of the quality signal bars.... but i have tried, and i saw that if the script isnt load again and the signal change, the bars, doesn't update because the quality signal don't change! i would like, if it's possible, that de speed update always speed change..... how can i do it?

 

Hmm... I don't quite understand what's going on with your code, but you can try messing around with the following lines:

-In the #Header:

Code:

 %Common.SetPriority(2500)

Setting that number to a lower value, say 500 or so, will make the bars update more often. The number is in milliseconds, so 1000 = 1 second.

-In the #GfxMode:

Code:

#GfxMode
%Common.ChangeScreen(5000,5)
%CleanUp.ClearVRAM()

Make sure the second line is there so it clears out the memory of the lcd each time it refreshes. This ensures the bars display correctly.

Also be aware that connection speed doesn't always change. The wireless connection speed will vary among certain predefined levels, measured in megabits per second, and indicates the maximum speed at a given moment, not the actual speed you are downloading/uploading.

 

Slight Topic Redirect: For those using Winamp and want to use both the visualization and the OLED readout, I've recently discovered and started using this little plugin: Visualisation MUX.

http://www.winamp.com/plugins/details/50923

I still use Winamp 2.95 so I can confirm it works (on 64-bit Windows at that). It will allow you to use both the Visualizations in Winamp and the OLED readout at the same time. Hope this offers some new possibilities to the rest of you. Who knows... Winamp Visualisation + OLED Readout + LED Lights...

 

Did you managed to make it work correctly ? Because I already used it with winamp's last version, and it made it crash often, and each time I launched winamp, I had to change several settings in the plugins section to make it work...

 

Hey guys, looking for a little help..I currently have 1 script where it shows Battery-Time-Cpu-Ram..thats perfect..

Now here is want i want to do..

Have another script that will:
Show CPU temps
HDD Temps
GPU temps

and so it loops between the 2 scripts or i can use a hotkey to switch between the 2...any help would be great...thanks guys

 

Just use the megascript, remove any unneeded scripts, re-touch the menus to match your taste. It's the perfect base

 

Have there been any attempts to modify the OLED in Windows XP? Is it possible? I'm learning to be a programmer, so I might be able to help, but I'm not sure how I would get access to the actual OLED. Is there any information I can find? I wouldn't mind setting it pixel by pixel if I had to...

 

Ok, i understand you.... you wants me to write this line to reload the script every 5 seconds... but, i have the mega script, and if i puts this lines, the wifiscript it will be running all the time, and the thing that i want is....
if i put autochange OFF in the mega script and i put wificript in the oled, i want the signal bars update everytime that my conection speed change... i means, like the download and updating rate that are always updating without relaoding script....
are you undertanding me???

 

Have you actually read the OLED thread start ? The OLED is already fully customizable on Windows XP, Vista (and should work on any other Windows OS)

 

The script itself runs as continuous program, it executes N times per second (which can be defined with %Common.SetPriority() ). That is, the code in the #GfxMode section repeats execution. You can make the bars update everytime that code executes or optimize it to read the signal strength on every 4-5 seconds. That is how all the scripts into the megascript are implemented and how all script ever are and should be written.

 

ok, this is that i want, but, How can i do that???
Do you want to see the code?

 

You have the biggest source to look at....the Megascript...every script in there is optimized, for example, look at the network/WiFi scripts.

It's a very simple method - create a variable, assign to it the current %System.Uptime() (the time windows is up, in miliseconds, very usefull in programming). Then, enclose the code that you want to "optimize" with a condition "systemtime - timeout > myvar" where timeout is the interval in milliseconds that you want the code inside the condition to execute:

PHP:

 %If(%Dec(%System.Uptime(), 4000) > %myvar() )
  Then{
         %Assign(myvar, %System.Uptime())
         / the code here will execute every 4 seconds /
         ....
         .... 
      } 


 

I apologize, I must have missed it. I still don't see it in the start of the thread. Is there a program I can use, or would I need to write one myself? Perhaps you could direct me to the posts in question. I'll give it another read over anyway. I was under the assumption that it was not possible to use the Vista program for XP.

 

is there a final version of the mega script for g50 series? i cant find it...

 

LCDHype works on both XP and Vista which is the app this thread is about.

 

Thank you. I've gotten it all to work now. Very much appreciated.

 

Thank you so much for this! OLED is much more usefull with this megascript.

Predator, any news about GLED Plugin for G50v backlighs and not touchpad light? =D

keep going man!

 

maybe do you like this? I uploaded the video few days ago.....

http://es.youtube.com/watch?v=VNXdzYp9waE

 

Sharing this would be awsome

 

Nice, I've written you a comment on the video, but let me say it again here
You have alot of free space in the network scripts, put download/upload graph there, see how it's implemented in the other scripts - make a global list and functions that will check it out on every 2 seconds, then if you are on those network screens, use that list values to fill in the graph

 

Awesome
Lets get this baby translated into English and rock and roll.

Nice song choice by the way, bloodhound gang, ha....

 

ufff predator! jajaj i saw the coment in the video... jajaj
i'm thinking about it... but i'm not sure if i am prepare to do that, i'm not a professional.... but maybe i will try to do it.... also i have to include in the wifi code, the lines you say me to fix the problem that i saw... (the signal bars not update unless i reload the script, do you remember?)

i have one question about the winamp peaks script... if i'm not wrong you base to blink leds with the first bar, isnt it???
y change that to the second bar, because i think second bar draw the drum... these bar usually takes better the rythm of the song than the first.... what do you think???

mmm how about the driver to leds??? is there any news ???

anyway, i'm glad with your program! I think it's great!!!

Pd: Are there lot of errors in my english??? i'm studing english and i want to improve my level of english.... i think this forum will be good for practise!!!

 

Any way to get this to work and still be able to overclock my CPU with direct console? Maybe a way to remove some files from the DC folder to disable its controll over the lcd screen?

I'm new to this so sorry if it sounds completely retarded.

 

Can anyone please help on where to download LCD Hype? the website is down.
I have an G50vt-X1 so is there any special drivers I need for it?

Thanks

 

Don't know what to tell you about LCD-Hype. The site worked for me earlier today. Did you try http://www.lcdhype.de.vu/ ?

You will need the driver for the OLED display to work with LCD-Hype. You can get that off of page 7 in this post. You're also going to need a script to tell LCD-Hype what to display on the screen. There are plenty on this post you can use.

 

Oh... I must be using the wrong site, because I've seen many websites that link to lcd hype but all of them don't work...

Thanks alot!

 

http://lcdhype.condense.de/

 

I know this is a retarded question and it has probably been awnserd before... But any way to change the refresh rate on the lcd screen?
I looked over the script I am using and couldn't find anything for it in there, but maybe I looked over it. I'm trying to get the CPU usage to update faster.

 

Look for
%Common.SetPriority(1000)
and change the value, it's the refresh rate in milliseconds : the lower the faster, but the faster, the most CPU usage...

 

Is there a way to set the priority of each segment of code seperately?

For example, I don't need my clock segment of the code to refresh every 10ms
I do, however, want my volume segment of the code to reset faster than 1 second.

 

Predator_MF gave a trick to do that in one of his lasts posts, using the SystemUptime command, I think you'll find it in the last 3 pages

 

Yes, he gave the trick when i asked for a similar thing, you will find in page 23 at the end!!!

Predator_MF, i tried this afthernoon to fix the problem of the quality bars, and i could to do it following your orders!!! Thanks a lot!!
now if i put the wifi script in autochange off, the quality bars are updating alone! without reload the script! it's like a movile phone with signal! It's cool!
You can see in my video, because i edited and updated in youtube!

http://es.youtube.com/watch?v=fyl-yGcV3aE

About to drow a graph with de up/down rates.... i don't think it will be a good idea.... i prefer to have less things but very clean, than more and not clear.... i don't know what can i do.....

 

Hey SICOPOLY what background is that? Looks really cool!

 

It's THE fomaus BattleShip!!!
you dont know OGAME??? althought maybe it's better that! It's too much adict!!!